Displej ADO
Nejběžnějším způsobem zobrazení dat ze sady záznamů je zobrazení dat v tabulce HTML.
Zobrazte názvy polí a hodnoty polí
Máme databázi s názvem „Northwind“ a chceme zobrazit data z tabulky „Zákazníci“ (nezapomeňte uložit soubor s příponou .asp):
Příklad
<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
for each x in rs.Fields
Response.Write(x.name)
Response.Write(" = ")
Response.Write(x.value & "<br>")
next
Response.Write("<br>")
rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>
Zobrazte názvy polí a hodnoty polí v tabulce HTML
Data z tabulky "Zákazníci" můžeme také zobrazit v tabulce HTML s následujícími řádky (nezapomeňte uložit soubor s příponou .asp):
Příklad
<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
<tr>
<%for each x in rs.Fields%>
<td><%Response.Write(x.value)%></td>
<%next
rs.MoveNext%>
</tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>
Přidejte záhlaví do tabulky HTML
Chceme do tabulky HTML přidat záhlaví, aby byla čitelnější (nezapomeňte uložit soubor s příponou .asp):
Příklad
<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
<tr>
<%for each x in rs.Fields
response.write("<th>" & x.name & "</th>")
next%>
</tr>
<%do until rs.EOF%>
<tr>
<%for each x in rs.Fields%>
<td><%Response.Write(x.value)%></td>
<%next
rs.MoveNext%>
</tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>
Další příklady
Jak přidat barvy do HTML tabulky, aby vypadala hezky.